XSL 기초

1. XSL 구조

2. XSLT 이해(1)

3. XSLT 이해(2)

4. XPath 이해

5. XSL Stylesheet 예제 (1)

6. XSL Stylesheet 예제 (2)

7. XSL Stylesheet 예제 (3)

8. XSL Stylesheet 예제 (4)

1. XSL 구조

들어 가기에 앞서..

XML이 인터넷상의 데이터 전송을 위해 설계되었다면, XSL은 이러한 XML문서를 처리하기 위해 설계되었다. XSL은 XML의 장점인 플랫폼 독립적이고, 언어 독립적이라는 점을 그대로 계승한 XML Application이라고 생각하면 쉽다. 이러한 XSL로 생성한 문서는 XSL 스타일 시트(StyleSheet)라고 불리며, DTD(Document Type Definition) 그리고, XML 문서와 함께 데이터로써의 가치를 지니게 된다.

1.1 XSL의 구성

XSL 은 크게 2 가지의 파트로 구성된다. 하나는 XML문서의 변환(Transformation)을 위한 언어, 다른 하나는 포맷팅 구문(Formatting Semantics)을 기술하기 위한 어휘(Vocabulary)로 이루어져있다. 변환을 위한 언어인 XSLT(XSL Transformations)는 XPath(XML Path Language)와 함께 사용하여 XSL의 기본 골격을 구성한다. 이러한 기본 골격위에 포맷팅을 위한 어휘를 사용하여 XML문서를 표현하기도 하지만, 다른 형태의 문서를 생성하기도 한다.

[그림 1] XSL 구성

그림1 에서 보이는 XSL 스타일 시트는 하나의 잘구성된(Well-Formed) XML 문서다. 최상위 엘리먼트(Element)인 xsl:sytlesheet와 xsl:template, xsl:apply-templates, fo:block은 모두 시작태그(Start-Tag)와 끝태크(End-Tag) 혹은 빈 태그(Empty Tag)로 구성되고, XML 원칙을 준수 하고 있다. XSL은 다양한 구성요소들을 포함하기 위해 네임스페이스(Namespaces)를 사용하여 각 구성요소의 엘리먼트들을 구분 및 처리 하도록 규정하고 있다. 네임스페이스에 사용되는 URI(Uniform Resource Identifier)는 스펙에 기술되어 있는 것을 사용한다.

 <xsl:stylesheet version="1.0"
   xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
   xmlns:fo="http://www.w3.org/1999/XSL/Format">

xsl:stylesheet는 XSLT의 최상위 엘리먼트로 XSL 스타일 시트에서 유일하도록 규정하며, 엘리먼트에 해당하는 속성을 기술하여 스타일 문서의 추가 정보를 나타내도록 한다. 즉, xsl:을 접두사로 갖는 엘리먼트 이름은 "http://www.w3.org/1999/XSL/Transform"의 엘리먼트로서 처리하라는 의미를 갖는다. fo:를 접두사로 갖는 엘리먼트 이름은 "http://www.w3.org/1999/XSL/Format"의 엘리먼트로서 처리하라는 의미를 갖는다. 여기서 xsl:은 XSL의 기본골격 및 최상위 엘리먼트에 사용되며, fo:는 포맷팅을 위한 엘리먼트에 사용된다.

XSL의 기본은 룰(Rule)들로 구성된다.(즉, 룰기반 처리가 이루어 진다는뜻) 룰은 XSLT의 엘리먼트중 template을 사용하며, 템플리트룰(Tempalte Rule) 혹은 생성규칙(Construction Rule)으로 불린다. 템플리트룰은 xsl:template 엘리먼트에 match 속성의 값인 패턴(Pattern)이라고 불리는 표현에 따라 처리된다. 이러한 표현은 XPath를 사용하며, XPath는 입력트리(Source Tree)인 XML문서에 접근하기 위한 언어다. 템플리트룰 내부에서 사용되는 xsl:apply-templates는 템플리트룰들을 연결하여 하나의 결과트리(Result Tree)를 생성하는 역할을 한다.

 <xsl:template match="/">
  <xsl:apply-templates select="block"/>
 </xsl:template>
  
 or
   
 <xsl:template match="block">
  <fo:block>
   <xsl:apply-templates/>
  </fo:block>
 </xsl:template>

[ 그림 2 ] XSLT/XPath/FO 관계

그림2 에서 처럼 XSLT는 룰의 영역내부에 포맷팅 객체나 변환후 결과를 위한 다른형식의 데이터를 포함할 수 있도록 되어있다. 또한 룰 처리를 위한 노드의 선택 및 처리 방법의 조건기술, 결과 트리에 삽입될 데이터 생성 등의 다양한 목적을 표현하기 위한 XPath를 기반으로 하고 있다.

2. XSLT 이해(1)

XSLT 표준안 상태에 대해..

XSLT는 1999년 11월 16일 현재 W3C(World Wide Web Consortium)에 XSLT 1.0 으로 권고(Recommendation) 되었고, 2000년 12월 12일 현재 XSLT 1.1 이 개발단계(Working Draft)에 있다.

2.1 XSLT 처리 개념

템플리트룰은 XSLT 지시(Instruction) 노드와 포맷팅 노드 등으로 구성된 단편적인 트리(Fragments Tree) 이다. 각 템플리트룰은 XPath 표현식을 포함한 XSLT 지시 노드와 관계되는 XML 엘리먼트 노드에 대한 접근 처리후, 결과트리인 단편트리가 생성된다. 또한 결과 단편 트리들은 템플리트룰중 연결을 위한 XSLT 지시 노드의 처리과정에 의해 하나의 트리 결과물로 산출된다.

[ 그림 1 ] XSLT 처리 개념

그림1의 XSLT 처리 개념도에서 XSL 스타일시트는 각각이 단편 트리로 구성된 템플리트룰들을 포함하고 있다. 템플리트룰의 지시노드는 XPath 표현 처리시 XML 문서인 입력 트리의 일부 노드에 접근한다. 템플리트룰의 단편 트리를 바탕으로, 또 다른 지시노드 처리에 의해 결과 트리를 하나의 단편 트리로 생성한다.

2.2 템플리트 매칭(Template Matching)

템플리트 매칭이란 쉽게 예기해서 입력 문서의 엘리먼트에 해당하는 템플리트룰을 적용시키는 것이다.

 <memo>
  <to>홍길동</to>
  <from>김돌쇠</from>
  <say>안녕하세요.<say>
 </memo>

 <xsl:template match="memo">
  ...
 </xsl:template>

위의 XML 문서는 <memo>엘리먼트를 루트(root)로 하는 트리가 그림2 에서 보여진다. 트리는 기술된 엘리먼트의 순서에 의해 깊이 우선 탐색을 통한 접근이 이루어 지도록 한다. 또한, <memo>엘리먼트에 해당하는 템플리트룰이 정의되어 있다.

[ ! ] 모든 XML 문서의 루트 엘리먼트 위에는 최상위 루트가 존재한다. 즉, XML 내용의 루트가 아닌 XML 문서의 루트를 의미한다. / 를 사용하여 XML 문서의 루트를 표시한다.

XSLT 프로세서는 XML 문서의 루트에서 부터 XML 문서에 접근하여 템플리트를 매칭시킨다. 이는 매우 단순한 방법으로 매칭되는데, 현재 노드를 기준으로 하여 템플리트 매칭이 결정된다. 최초의 현재 노드는 문서의 루트인 / 이다. 때문에 XSLT 프로세서는 템플리트룰중에 / 을 패턴으로 하는 템플리트를 찾는다. 즉, 최초로 시작되는 템플리트룰은 다음과 같다.

 <xsl:template match="/">
  <xsl:apply-templates/>
 </xsl:template>

위의 템플리트가 매칭된 후에 새로운 현재 노드를 선택하기 위해 <xsl:apply-templates/>를 사용했다. 이는 현재 노드(여기서는 / )의 자식 노드들을 반복적으로 선택후 템플리트룰을 적용하라는 의미다. 즉, / 의 자식 노드인 <memo> 가 선택되고 이에 해당하는 템플리트가 매칭된다.

<xsl:apply-templates/>가 현재 노드의 모든 자식 엘리먼트들을 반복적으로 선택하라는 의미 이외에 select 속성을 사용하여 매칭시킬 자식노드 및 특정 노드를 선택 할 수 있다. 즉, 다음과 같이 사용할 수 있다.

 <xsl:apply-templates select="memo"/>

 <xsl:apply-templates select="memo/from"/>

 <xsl:apply-templates select="."/>

select 속성값으로 "memo" 는 절대경로로 나타내면 "/memo" 라는 의미로 현재노드는 <memo> 이고, "memo" 를 패턴으로 하는 템플리트를 매칭시킨다. 속성값으로 "memo/from" 는 현재 노드가 <from> 이고, "memo/from" 을 패턴으로 하는 템플리트를 매칭시킨다. (혹은 "from" 을 패턴으로 하는 템플리트를 매칭, 이는 우선순위에 준한다.) 속성값으로 "." 는 현재 노드 그 자체이므로, 무한 루프에 빠질수 있다.

2.3 템플리트 예제

다음은 2.2 의 XML 문서에 대한 완전한 XSL 스타일 시트를 보여준다.

 <xsl:stylesheet version="1.0"
   xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

  <xsl:template match="/">
   <HTML>
    <xsl:apply-templates/>
   </HTML>
  </xsl:template>

  <xsl:template match="memo">
   <xsl:apply-templates select="say"/>
   <xsl:apply-templates select="from"/>
   <xsl:apply-templates select="to"/>
  </xsl:template>

  <xsl:template match="say">
   <H1>
    <xsl:value-of select="."/>
   </H1>
  </xsl:template>

  <xsl:template match="from">
   <H2>
    <xsl:value-of select="."/>
   </H2>
  </xsl:template>
    
  <xsl:template match="to">
   <H3>
    <xsl:value-of select="."/>
   </H3>
  </xsl:template>   

 </xsl:stylesheet>

다음 그림2는 위의 템플리트룰들이 처리되는 과정을 보인다.

[ 그림 2 ] 템플리트 매칭 과정

스타일시트는 5개의 템플리트룰을 트리 노드로 구성하고 있으며, 각 템플리트룰은 템플리트 매칭에 의해 그림2와 같이 연결된다. <xsl:value-of> 는 select로 선택된 노드의 텍스트 노드의 값을 삽입한다.

최종 변환 결과는 다음과 같다.

 <HTML>
  <H1>안녕하세요.</H1>
  <H2>김돌쇠</H2>
  <H3>홍길동</H3>
 </HTML>

3. XSLT 이해(2)

3.1 XSLT 엘리먼트(XSLT Eelement)

Stylesheet Element [§2.2]

 <xsl:stylesheet
  id = id 
  extension-element-prefixes = tokens 
  exclude-result-prefixes = tokens 
  version = number>
   <!-- Content: (xsl:import*, top-level-elements) -->
 </xsl:stylesheet>

 <xsl:transform
  id = id 
  extension-element-prefixes = tokens 
  exclude-result-prefixes = tokens 
  version = number>
   <!-- Content: (xsl:import*, top-level-elements) -->
 </xsl:transform>

[ ! ] xsl:stylesheet 와 xsl:transform 는 동의어로 사용함

Stylesheet Inclusion [§2.6.1]

 <xsl:include href = uri-reference/>

Stylesheet Import [§2.6.2]

 <xsl:import href = uri-reference/>

Whitespace Stripping [§3.4]

 <xsl:strip-space elements = tokens/>

 <xsl:preserve-space elements = tokens/>

Defining Template Rules [§5.3]

 <xsl:template 
  match = number 
  name = id 
  priority = tokens 
  mode = tokens>
   <!-- Content: (xsl:param*, template) -->
 </xsl:template>

Applying Template Rules [§5.4]

 <xsl:apply-templates select = node-set-expression 
  mode = qname/>

 <xsl:apply-templates 
  select = node-set-expression 
  mode = qname>
   <!-- Content: (xsl:sort | xsl:with-param)* -->
 </xsl:apply-templates>

Overriding Template Rules [§5.6]

 <xsl:apply-imports/>

Named Templates [§6]

 <xsl:call-template name = qname/>

 <xsl:call-template 
  name = qname>
   <!-- Content: xsl:with-param* -->
 </xsl:call-template>

Namespace Alias [§7.1.1]

 <xsl:namespace-alias 
  stylesheet-prefix = prefix | "#default" 
  result-prefix = prefix | "#default"/>

Creating Elements [§7.1.2]

 <xsl:element 
  name = { qname } 
  namespace = { uri-reference } 
  use-attribute-sets = qnames>
   <!-- Content: template -->
 </xsl:element>

Creating Attributes [§7.1.3]

 <xsl:attribute 
  name = { qname } 
  namespace = { uri-reference }>
   <!-- Content: template -->
 </xsl:attribute>

Named Attribute Sets [§7.1.4]

 <xsl:attribute-set 
  name = qname 
  use-attribute-sets = qnames>
   <!-- Content: xsl:attribute* -->
 </xsl:attribute-set>

Creating Text [§7.2]

 <xsl:text
  disable-output-escaping = "yes" | "no">
   <!-- Content: #PCDATA -->
 </xsl:text>

Creating Processing Instructions [§7.3]

 <xsl:processing-instruction
  name = { ncname }>
   <!-- Content: template -->
 </xsl:processing-instruction>

Creating Comments [§7.4]

 <xsl:comment>
  <!-- Content: template -->
 </xsl:comment>

Copying [§7.5]

 <xsl:copy
  use-attribute-sets = qnames>
   <!-- Content: template -->
 </xsl:copy>

Generating Text [§7.6.1]

 <xsl:value-of
  select = string-expression
  disable-output-escaping = "yes" | "no"/>

Attribute Value Templates [§7.6.2]

 <element attribute = "{expression}"/>

Numbering [§7.7]

 <xsl:number 
  level = "single" | "multiple" | "any" 
  count = pattern 
  from = pattern 
  value = number-expression 
  format = { string } 
  lang = { nmtoken } 
  letter-value = { "alphabetic" | "traditional" } 
  grouping-separator = { char } 
  grouping-size = { number }/>

Repetition [§8]

 <xsl:for-each
  select = node-set-expression>
   <!-- Content: (xsl:sort*, template) -->
 </xsl:for-each>

Conditional Processing [§9]

 <xsl:if
  test = boolean-expression>
   <!-- Content: template -->
 </xsl:if>   
 
 <xsl:choose>
  <!-- Content: (xsl:when+, xsl:otherwise?) -->
 </xsl:choose>   

 <xsl:when
  test = boolean-expression>
   <!-- Content: template -->
 </xsl:when>   

 <xsl:otherwise>
  <!-- Content: template -->
 </xsl:otherwise>

Sorting [§10]

 <xsl:sort 
  select = string-expression 
  lang = { nmtoken } 
  data-type = { "text" | "number" | qname-but-not-ncname } 
  order = { "ascending" | "descending" } 
  case-order = { "upper-first" | "lower-first" }/>

Variables and Parameters [§11]

 <xsl:variable name = qname 
  select = expression/>

 <xsl:variable 
  name = qname>
   <!-- Content: template -->
 </xsl:variable>   
 
 <xsl:param name = qname 
  select = expression/>

 <xsl:param 
  name = qname>
   <!-- Content: template -->
 </xsl:param>

Using Values of Variables and Parameters [§11.3]

 <xsl:copy-of
  select = exprssion/>

Passing Parameters to Templates [§11.6]

 <xsl:with-param name = qname
  select = expression/>

 <xsl:with-param
  name = qname>
   <!-- Content: template -->
 </xsl:with-param>

Key [§12.2]

 <xsl:key
  name = qname
  match = pattern
  use = expression/>

Number Formatting [§12.3]

 <xsl:decimal-format 
  name = qname 
  decimal-separator = char 
  grouping-separator = char 
  infinity = string 
  minus-sign = char 
  NaN = string 
  percent = char 
  per-mille = char 
  zero-digit = char 
  digit = char 
  pattern-separator = char/>

Messages [§13]

 <xsl:message 
  terminate = "yes" | "no">
   <!-- Content: template -->
 </xsl:message>

Fallback [§15]

 <xsl:fallback>
   <!-- Content: template -->
 </xsl:fallback>

Output [§16]

 <xsl:output 
  method = "xml" | "html" | "text" | qname-but-not-ncname 
  version = nmtoken 
  encoding = string 
  omit-xml-declaration = "yes" | "no" 
  standalone = "yes" | "no" 
  doctype-public = string 
  doctype-system = string 
  cdata-section-elements = qnames 
  indent = "yes" | "no" 
  media-type = string/>   

 Key

 xsl:stylesheet  Element
 version   반드시 요구되는 속성(Required attribute)
 version   선택적으로 존재하는 속성(Optional attribute)
 {expression}  Attribute value template
 template   템플리트내에서 어떤것도 허용
 |   양자 택일 구분(or)
 ?   0번 혹은 한번 반복
 *   0번 이상 반복
 +   1번 이상 반복
 #PCDATA   파싱된 문자 데이터

 Attribute Value Type
  
 boolean-expression  불 논리연산(Boolean)값을 돌려주는 표현
 char   단일 문자
 expression  표현
 id   식별자(identifier)로 사용되는 XML 이름 
 ncname   qname에서 접두사(prefix)와 콜론(:)을 제외한 XML 이름
 nmtoken   이름 토큰(Name token)
 node-set-expression 집합노드를 돌려주는 표현
 number   리터럴 값(Literal value)으로 여기서는 1.0 을 사용
 number-expression  숫자를 돌려주는 표현
 pattern   XSLT pattern
 prefix   네임스페이스(Namespace) 접두사
 qname   옵션인 접두사와 ncname을 포함하는 적격한 네임스페이스의 XML 이름
 qname-but-not-ncname 접두사와 ncname을 포함하는 적격한 네임스페이스 이름
 string-expression  문자열 표현
 token   토큰
 uri-reference  URI 참조

3.2 XSLT 함수들(XSLT Functions)

node-set document( object, node-set? ) [§12.1]

node-set key( string, obejct ) [§12.2]

string format-number( number, string, string? ) [§12.3]

node-set current( ) [§12.4]

string unparsed-entity-uri( string ) [§12.4]

string generate-id( node-set? ) [§12.4]

object system-property( string ) [§12.4]

boolean element-available( string ) [§15]

boolean function-available( string ) [§15]

4. XPath 이해

XPath 표준안 상태에 대해..

XPath는 XSLT 1.0과 함께 1999년 11월 16일 현재 W3C(World Wide Web Consortium)에 XPath 1.0 으로 권고(Recommendation) 되어있다. XPath는 XSLT의 표현 언어(Expression language)로써 XSLT의 속성에서 사용된다.

XPath는 XML 문서의 특정 엘리먼트(속성,PI ..) 위치를 어떻게 기술하는지 등의 기본적인것을 제공하며, 간결하게 표현 할 수 있다. 또한 XPath는 XSLT와 XPointer에서 기반으로 사용되도록 설계되어 있다. 때문에 XPath는 문자열 기반의(String-based) 문법을 바탕으로 속성이나 URIs 에서 표현 가능하다. 그러나, XSLT와 XPointer에서 사용되는 XPath가 완전히 동일하지 않기때문에 핵심 함수(Core Function)를 두어 기능적으로 같도록 한다.

4.1 XPath 데이터 모델(Data Model)

XPath의 데이터 모델은 논리적인(Logical) 트리로서 XML 문서를 다룬다. 논리적 트리는 각 노드를 타입으로 구분하여, 타입에는 엘리먼트(Element), 속성(Attribute), 텍스트(text), 처리지시(Processing Instruction), 주석(Comment), 네임스페이스(Namespace), 루트(Root)가 있다. 실제 문서를 트리로 표현할때 물리적인 트리에 비해 논리적인 트리는 처리과정이 독립적일 수 있다.

[ 그림 1 ] XPath 데이터 모델

그림1 에서 좌측부분이 실제 문서를 물리적인 트리로 표현한 것이고, 우측이 논리적으로 트리를 표현한 것이다. /는 Root로, <doc>, <para>, <em> 엘리먼트들은 모두 E로 대응되고, <?Pub Caret?>는 PI로, "Some", "emphasis" 등의 문자열들은 Text로 대응된다. 이처럼 그림1은 물리적인 트리의 노드를 일반화시켜 논리적인 노드의 트리로 보여준다. XPath는 이러한 논리적 트리에서 노드들을 다루고, 핵심 함수들을 사용하여 세부적인 기능들을 이용하도록 설계되어 있다.

4.2 표현 구조(Expression Syntax)

XPath는 XSLT의 패턴(Pattern)에 사용되는 위치경로(Location Path)와 이를 포함하며 좀더 다양한 표현을 위한 표현법(Expressions)이 있다. 완전한 표현언어(Expression Language)는 위치경로와 위치경로 이상의 표현, 그리고 다양한 계산을 수행하고 객체(Object)를 비교하기 위한 연산자(operators), 다양한 타입 분석 및 관리를 위한 함수를 사용하여 표현할 수 있다.

[ ! ] XSLT 패턴에 사용되는 패턴언어(Pattern Language)는 XPath의 일부분으로 볼수 있지만, XSLT 템플리트 매칭에 제한적이고 약간의 표현만을 허용하는 XSLT 표준이다. 그러므로, XSLT 패턴 언어와 XPath 의 표현 언어(Expression Language)는 다르다고 볼 수 있다.

위치경로(Location Path)는 절대경로(Absolute Location Path)와 상대경로(Relative Location Path)로 표현될 수 있다. 절대경로는 문서 구조상 최상위 노드인 루트( /)에서 시작해 원하는 위치까지의 경로를 표현한다. 상대경로는 현재노드(Current Node)에서 시작해 원하는 위치까지의 경로를 표현한다.

경로는 단계(스텝:Step)들로 구성되며, step은 기초부(베이시스:Basis)와 술어부(프리디케이트:Predicate)로 구성된다. basis는 축(엑시스:Axis)과 노드검사(노드테스트:Node Test)로 구성되며, 생략가능한 predicate는 대괄호(square bracket)로 묶인 표현식으로 구성된다. axis는 13개의 축이름(엑시스네임:Axis Name)과 더블 콜론(::)으로 구성되고, node test는 엘리먼트 이름이나 노드 타입(Node Type : node, comment, text, processing-instruction)으로 구성된다.

Axis Name

Node Test

 
ancestor::
ancestor-or-self::
attribute::
child::
descendant::
descendant-or-self::
following::
following-sibling::
namespace::
parent::
preceding::
preceding-sibling::
self::   
name
URI:name
prefix:name
*
prefix:*
node()
comment()
text()
processing-instruction()
processing-instruction(literal)

[ ! ] attribute:: axis는 attribute 노드의 개념이고,namespace:: axis는 namespace 노드의 개념이다.. 다른 axes는 element 노드에 대응 되는 개념이다.

[ 그림 2 ] 위치경로(location path)

그림2는 위치경로의 간단한 예제를 보여준다. step은 "/"로 구분하고, 오른쪽에서 부터 왼쪽으로 읽어 매치시킨다. 즉, 가장 오른쪽이 현재노드를 나타낸다. 첫번째 step은 axis와 node test로 구성 되었고, axis name은 following을 사용했다. 두번째 step은 엘리먼트 이름과 Predicate로 구성되었다. 마지막 세번째 step은 엘리먼트 이름으로만 구성되어 있다.

[ 그림 3 ] Axes

그림3은 axes에 대해 해석한 그림이다. 현재노드(current node)이자 self:: axis name은 회색으로 표시된 노드를 가르킨다. 그림3의 좌측은 ancestor::, preceding-sibling::, following-sibling::, child:: axis name을 표시하며, 노드안의 숫자는 참조되는 순서다. 우측은 preceding::, following, descendant:: axis name을 표시한다. ancestor-or-self:: axis name은 현재노드를 포함한 ancestor:: 를 의미하며, descendant-or-self:: axis name은 현재노드를 포함한 descendant:: 를 의미한다. parent:: axis name은 현재노드의 부모 노드를 의미한다. attribute:: axis는 컨택스트 노드(Context node)의 attribute를 포함하며, namespace:: axis는 컨택스트 노드의 namespace를 포함한다.

[ ! ] 컨택스트 노드(Context Node) : XSLT나 XPointer의 XPath 표현 문맥상 결정되는 노드를 의미하며 노드(context node), 숫자(context position : context size), 연결된 변수 집합, 함수, 표현을 위해 선언된 네임스페이스 집합 등이 될 수 있다. 보통 현재노드를 의미한다.

4.3 단축법(Abbreviated Syntax)

XPath에는 표현의 간략화를 위해 필요없는 표현을 생략하거나 대치하는 방법을 사용한다.

가장 대표적인 child::는 디폴트(default)로 쓰이는 axis로써 보통 생략된다.

 div/para = child::div/child::para

attribute:: axis 는 @ 로 대치되어 사용되기도 한다.

 para[@type="warning"] = child::para[attribute::type="warning"]

모든 엘리먼트에 대응되는 표현으로 *를 사용하거나, 모든 어트리뷰트에 대응되는 @*를 사용하기도 한다.

 * = child::*
 @* = attribute::*

현재 노드 즉, self::node()를 간략화 시킨 .을 사용하기도 한다.

 ./para  = self::node()/child::para

부모 노드 즉, parent::node()를 간략화 시킨 ..을 사용하기도 한다.

 ../title = parent::node()/child::title

특별히 //를 사용하여 컨트스트 노드의 모든 후손노드(/descendants-or-self::node())를 선택할 수 도 있다.

 .//para  = self::node()/descendant-or-self::node()/child::para

루트노드는 /로 나타낸다.

 

4.4 기타 표현식

Booleans

or , and , = , != , <= , < , >= , >

Numbers

+ , - , div , mod

4.5 XPath Syntax Sample

단축하지 않은 표현(unabbreviated syntax) vs 단축 표현(Abbreviated Syntax)

child::para para
컨택스트 노드의 모든 자식 노드중 para 엘리먼트인것 선택
child::* *
컨택스트 노드의 모든 자식 엘리먼트 선택
child::text() text()
컨택스트 노드의 모든 자식 텍스트 노드 선택  
attribute::name @name
컨택스트 노드의 name 어트리뷰트 선택
attribute::* @*
컨택스트 노드의 모든 어트리뷰트 선택
child::chapter/descendant::para chapter//para
컨택스트 노드의 자식 노드가 chapter 엘리먼트이고, chapter 엘리먼트의 후손 노드가 para 엘리먼트인것 선택
child::*/child::para */para
컨택스트 노드의 손자 노드가 para 엘리먼트인것 선택
/descendant::para //para
문서내의 모든 para 엘리먼트 선택
/descendant::olist/child::item //olist/item
문서내에서 olist 엘리먼트를 부모로 가지는 모든 item 엘리먼트 선택
child::para[position()=1] para[1]
컨택스트 노드의 모든 자식 노드중 첫번째 para 엘리먼트 선택 
child::para[position()=last()] para[last()]
컨택스트 노드의 모든 자식 노드중 마지막 para 엘리먼트 선택
/child::doc/child::chapter[position()=5]/child::section[position()=2] /doc/chapter[5]/section[2]
문서의 doc 엘리먼트의 5번째 자식 chpater 엘리먼트의 2번째 자식 section 엘리먼트 선택
child::para[attribute::type="warning"] para[@type="warning"]
컨택스트 노드의 type 얼트리뷰트 값이 'warning' 인 모든 자식 para 엘리먼트 선택
child::para[attribute::type='warning'][position()=5] para[@type="warning"][5]
컨택스트 노드의 type 얼트리뷰트 값이 'warning' 인 모든 자식 para 엘리먼트중 5 번째 para 엘리먼트 선택
child::para[position()=5][attribute::type="warning"] para[5][@type="warning"]
컨택스트 노드의 5번째 para 엘리먼트의 type 어트리뷰트 값이 'warning' 이라면 선택 
child::chapter[child::title='Introduction'] chapter[title="Introduction"]
컨택스트 노드의 모든 자식 chapter 엘리먼트중 자식 title 엘리먼트의 텍스트 노드 스트링 값이 'Introduction' 인것 선택
child::chapter[child::title] chapter[title]
컨택스트 노드의 모든 자식 chapter 엘리먼트중 자식이 title 엘리먼트 인것 선택

단축하지 않은 표현(unabbreviated syntax)

child::node()
컨택스트 노드의 모든 자식노드(노드타입에 상관없는) 선택
descendant::para
컨택스트 노드의 후손 노드가 para 엘리먼트인것 선택
ancestor::div
컨택스트 노드의 모든 조상 노드중 div 엘리먼트인것 선택
ancestor-or-self::div 
컨택스트 노드의 모든 조상 노드중 div 엘리먼트인것(컨택스트 노드가 div 엘리먼트라면 컨택스트 노드 포함) 선택
descendant-or-self::para      
컨택스트 노드의 모든 후손 노드중 para 엘리먼트인것(컨택스트 노드가 para 엘리먼트라면 컨택스트 노드 포함) 선택
self::para 
컨택스트 노드가 para 엘리먼트라면 선택하고 아니라면 아무것도 선택 안함
/
문서의 루트 선택(문서에서 항상 최상위 노드임)
child::para[position()=last()-1] 
컨택스트 노드의 모든 자식 para 엘리먼트 노드중 마지막 바로 이전 선택
child::para[position()>1]
컨택스트 노드의 모든 자식 prar 엘리먼트 노드중 첫번째 이후 선택
following-sibling::chapter[position()=1] 
컨택스트 노드의 다음 형제 chapter 엘리먼트 선택
preceding-sibling::chapter[position()=1] 
컨택스트 노드의 이전 형제 chapter 엘리먼트 선택
/descendant::figure[position()=42] 
문서내의 42번째 figure 엘리먼트 선택
child::*[self::chapter or self::appendix] 
컨택스트 노드의 자식 노드가 appendix 엘리먼트이거나 chapter 엘리먼트인것 선택
child::*[self::chapter or self::appendix][position()=last()] 
컨택스트 노드의 마지막 자식 chapter 엘리먼트 혹은 마지막 자식 appendix 엘리먼트 선택

단축 표현(Abbreviated Syntax)

.
컨택스트 노드 선택
.//para
컨택스트 노드의 모든 후손 para 엘리먼트 선택
..
컨택스트 노드의 부모 선택
../@lang
컨택스트 노드 부모의 lang 어트리뷰트 선택
employee[@secretary and @assistant]
컨택스트 노드의 모든 자식 employee 엘리먼트중 secretary 어트리뷰트와 assistant 어트리뷰트를 가진 employee 엘리먼트 선택

4.6 XPath 핵심 함수(Core Functions)

Node Set Functions

number last() [§4.1]

number position() [§4.1]

number count(node-set) [§4.1]

node-set id(object) [§4.1]

string local-name(node-set?) [§4.1]

string namespace-uri(node-set?) [§4.1]

string name(node-set?) [§4.1]

String Functions

string string(object?) [§4.2]

string concat(string, string, string*) [§4.2]

boolean starts-with(string, string) [§4.2]

boolean contains(string, string) [§4.2]

boolean substring-before(string, string) [§4.2]

string substring-after(string, string) [§4.2]

string substring(string, number, number?) [§4.2]

number string-length(string?) [§4.2]

string normalize-space(string?) [§4.2]

string translate(string, string, string) [§4.2]

Boolean Functions

boolean boolean(object) [§4.3]

boolean not(object) [§4.3]

boolean true() [§4.3]

boolean false() [§4.3]

boolean lang(string) [§4.3]

Number Functions

number number(object?) [§4.4]

number sum(node-set) [§4.4]

number floor(number) [§4.4]

number ceiling(number) [§4.4]

number round(number) [§4.4]

5. XSL Stylesheet 예제 (1)

간단한 XSL 스타일시트의 예제로써 먼저 이력서를 만들어본다.

5.1 이력서 DTD

먼저 DTD를 만드는 이유는 간단히 설명하겠다. 스타일시트를 만들기 위한 가장 중요한 이유는 XML 문서의 구조를 알아야 스타일시트를 만들 수 있기 때문이다.

다음 이력서 DTD는 Internet Explorer 에 적합하도록 설계되었으며, 최적화된 DTD는 아니다.

[ ! ] 다음 이력서는 가장 일반적으로 사용하는 이력서 서식만을 참조하여 설계하였다. 때문에 다른 이력서 서식과 맞지 않는 부분이 있을수 있다. 따라서 본 DTD를 사용하여 발생하는 피해는 본인에게 책임이 없다.

다음은 profile.dtd 이다.

 <!-- 이 DTD는 이력서를 위해 제작 되었습니다.    -->
 <!-- 이 DTD의 이용과 배포는 주석의 삭제및 수정이 없는한 자유입니다.  -->
 <!-- 추가는 가능합니다만 본인에게 통보해주십시요!   -->
 <!-- 배재대학교 멀티미디어 연구실 / 이형문    -->
 <!-- http://mie.paichai.ac.kr/     -->
 <!-- 2000.03.27 / darkness@nate.com   -->

<!-- Standalone Parameter Entity Declarations used in the DTD  -->

<!ENTITY % doctype "이력서">

<!ENTITY % p.date  "년|월|일">
<!ENTITY % p.bth.day "나이|(%p.date;)">
<!ENTITY % p.pi.num "앞자리,뒷자리">
<!ENTITY % m.fig  "EMPTY">
<!ENTITY % m.ph.addr "국명|시|도|군|구|읍|면|동|우편번호|사서함번호|전화번호|팩스번호|전자우편번호">

<!-- Mixed Parameter Entity Declarations used in the DTD  -->

<!ENTITY % m.addr  "#PCDATA | %m.ph.addr;">
<!ENTITY % m.lib  "(%p.date;)*, 내용,비고?">

<!-- Entities for common attributes     -->

<!ENTITY % a.id  "ID ID #IMPLIED">
<!ENTITY % a.lang  "(한글|영어|한자|일본어) '한글'">
<!ENTITY % b.type  "(양력|음력) '양력'">

<!--  Notation Declarations     -->

<!NOTATION  jpg   PUBLIC "">

<!--  Element Delclarations     -->

<!ELEMENT %doctype; (이름+,사진?,주민등록번호,생년월일,주소,호적관계,(학력|경력|특기|자격)*)>

<!--  이름          -->

<!ELEMENT 이름  (#PCDATA)>
<!ATTLIST 이름  언어 %a.lang;>

<!--  사진          -->

<!ELEMENT 사진  %m.fig;>
<!ATTLIST 사진  %a.id;
   NAME     ENTITY  #IMPLIED>

<!--  주민등록번호         -->

<!ELEMENT 주민등록번호 (%p.pi.num;)>
<!ELEMENT 앞자리  (#PCDATA)>
<!ELEMENT 뒷자리  (#PCDATA)>

<!--  생년월일          -->

<!ELEMENT 생년월일  (%p.bth.day;)+>
<!ATTLIST 생년월일  책력 %b.type;>

<!ELEMENT 나이  (#PCDATA)>
<!ELEMENT 년  (#PCDATA)>
<!ELEMENT 월  (#PCDATA)>
<!ELEMENT 일  (#PCDATA)>

<!--  주소          -->

<!ELEMENT 주소  (%m.addr;)*>
<!ELEMENT 국명  (#PCDATA)>
<!ELEMENT 시  (#PCDATA)>
<!ELEMENT 도  (#PCDATA)>
<!ELEMENT 군  (#PCDATA)>
<!ELEMENT 구  (#PCDATA)>
<!ELEMENT 읍  (#PCDATA)>
<!ELEMENT 면  (#PCDATA)>
<!ELEMENT 동  (#PCDATA)>
<!ELEMENT 우편번호  (#PCDATA)>
<!ELEMENT 사서함번호 (#PCDATA)>
<!ELEMENT 전화번호  (#PCDATA)>
<!ELEMENT 팩스번호  (#PCDATA)>
<!ELEMENT 전자우편번호 (#PCDATA)>

<!--  호적관계          -->

<!ELEMENT 호적관계  (호주성명,관계)>
<!ELEMENT 호주성명  (#PCDATA)>
<!ELEMENT 관계  (#PCDATA)>

<!--  학력, 경력, 특기, 자격    -->

<!ELEMENT 학력  (%m.lib;)>
<!ELEMENT 경력  (%m.lib;)>
<!ELEMENT 특기  (%m.lib;)>
<!ELEMENT 자격  (%m.lib;)>

<!ELEMENT 내용  (#PCDATA)>
<!ELEMENT 비고  (#PCDATA)>

5.2 이력서 XML 문서

다음은 profile.xml 이다.

<?xml version="1.0" encoding="euc-kr"?>
<?xml-stylesheet type="text/xsl" class='MIME' href="profile.xsl"?>
<!DOCTYPE 이력서 SYSTEM "profile.dtd" [
 <!ENTITY profile SYSTEM "profile.jpg" NDATA jpg>
]>
<이력서>
 <이름 언어="한글">홍길동</이름>
 <사진 ID="pic01" NAME="profile"/>
 <주민등록번호>
  <앞자리>xxxxxx</앞자리>
  <뒷자리>xxxxxxx</뒷자리>
 </주민등록번호>
 <생년월일 책력="양력">
  <나이>18</나이>
  <년>1800</년>
  <월>12</월>
  <일>30</일>
 </생년월일>
 <주소>
  대한민국 대한민국시 대한민국동
  <전화번호>02-1234-5678</전화번호>
  <전자우편번호>kdhong@korea.com</전자우편번호>
 </주소>
 <호적관계>
  <호주성명>홍대감</호주성명>
  <관계>서자</관계>
 </호적관계>
 <학력>
  <년>1810</년>
  <월>3</월>
  <일>2</일>
  <내용>길동 서당 졸업</내용>
 </학력>
 <학력>
  <년>1820</년>
  <월>2</월>
  <일>25</일>
  <내용>의적 교육소 졸업</내용>
  <비고>의적대 20(의) 109</비고>
 </학력>
 <경력>
  <년>1821</년>
  <내용>악덕 김대감 창고 절도</내용>
  <비고>쌀 200 섬</비고>
 </경력>
 <자격>
  <년>1819</년>
  <월>10</월>
  <일>12</일>
  <내용>의적 자격증 1급</내용>
  <비고>의적인력공단</비고>
 </자격>
 <특기>
  <년>2001</년>
  <월>11</월>
  <내용>대한민국 국회의사당 출몰</내용>
  <비고>부활(?)</비고>
 </특기>
</이력서>

5.3 이력서 XSL 스타일시트

다음은 profile.xsl 이다.

아래 소스는 profile.xsl 에서 사용된 앞부분이다.

XSL 스타일 시트 또한 XML 문서다.
<?xml version="1.0" encoding="euc-kr"?>

M$의 Tip란에 올라온 내용으로, 스타일 시트 내에서 공백(space)를 표현하기 위한 엔티티 선언 
HTML 포맷팅을 사용할 경우에만 가능하며, non-Validation 으로 처리된다.
<!DOCTYPE xsl:stylesheet [
 <!ENTITY nbsp "&#160;" > 
]>

XSLT의 최상위 엘리먼트
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 
default는 html 이지만 M$의 Processor의 버그 때문에 임시로 사용(後에설명)
<xsl:output method="xml" version="1.0" encoding="euc-kr"/>

다음 소스는 profile.xsl 에서 가장 먼저 매치되는 템플리트로써, 결과 HTML 문서의 골격을 이룬다.

최초의 컨택스트 노드는 문서의 루트(/) 이므로, 최초의 매치 템플리트
<xsl:template match="/">
 <HTML>
 <HEAD>
 <STYLE>
  Link 를 위한 스타일 설정
  a {text-decoration: none; color: black}
  a:hover {color: blue; font-weight: bold}
  
  연락처를 위한 스타일 설정
  .call {text-align: right; font-size: 15pt;}

  사진이 들어갈 Table Cell의 스타일 설정(일반적인 Table Cell의 스타일 설정)
  th, td{font-size: 10pt; background: #ccffff}

  "이력서" 의 제목이 들어갈 Table Cell의 스타일 설정
  .top {font-size: 20pt; background: #ccffff}

  "성명, 생년월일, 주민번호" 가 들어갈 Table Cell의 스타일 설정
  .theader {font-size: 14pt; background: #ccffff}    

  "주소, 호적관계" 가 들어갈 Table Cell의 스타일 설정
  .title {height: 30pt; font-size: 14pt; background: #ccffff} 

  "학력, 경력, 자격, 특기" 가 주석으로 들어갈 Table Cell의 스타일 설정
  .comment {height: 40pt; background: #ccffcc}    
  
  실제 XML 데이터가 들어갈 Table Cell의 스타일 설정
  .titem {height: 30pt; background: #ffffcc}     
  
  실제 XML 데이터가 없을때의 Table Cell의 스타일 설정
  .null {}             
 </STYLE>
 </HEAD>
 <BODY>
  다음 매치할 템플리트 선택(이부분에 끼워넣어질 데이터를 위해)
  <xsl:apply-templates select="이력서"/>
 </BODY>
 </HTML>
</xsl:template>

다음회에 계속......

6. XSL Stylesheet 예제 (2)

6.1 이력서 XSL 스타일시트

다음은 profile.xsl 이다.

다음 소스는 이력서의 표를 구성하기 위한 템플리트로써, 표의 주석부분과 매치시킬 템플리트 순서를 처리한다.

템플리트를 매치시킬 순서와 위치 그리고 반복에 유의한다.

[ ! ] xsl:apply-templates 을 사용하여 매치 시킬 템플리트가 없을경우, 하위 데이터들은 모두 하나의 텍스트 데이터로 처리 가능하다. 즉, 컨택스트 노드가 하위 전체 노드 셋을 의미하고 xsl:value-of 를 사용한것과 같은 의미가 된다. 보통 하위 엘리먼트가 절대 없을경우 xsl:value-of 를 사용하고, 하위 템플리트 구성을 위해 xsl:apply-templates 을 사용한다. xsl:apply-templates을 사용할경우 매치될 템플리트에 주의하지 않으면 어뚱한 결과가 나오기도 한다.

현재의 컨택스트 노드는 profile.xml 문서의 루트인 "이력서" 로써, 템플리트 매치된다.
<xsl:template match = "이력서">
 <TABLE width="620pt" border='1' CELLSPACING="0" CELLPADDING="0" align="center">
   
 "연락처:" 와 문서에서 첫번째로 접근되는 전화번호 값을 입력(위 팁[!] 참조)
 <DIV class="call">연 락 처 : <xsl:apply-templates select="//전화번호[1]"/></DIV>

 '사진' 템플리트와 "이 력 서" 주석 입력
 <TR>
  <TD colspan='3' rowspan='4' width="15%" style="text-align: center">
   현재 위치에 다음 템플리트를 매치("이력서"의 하위 노드중 "사진" 에 해당하는 템플리트 매치)
   <xsl:apply-templates select="사진"/>
  </TD>
  <TD class="top" colspan='5' height="50pt" style="font-weight: bold; text-align: center">
   이&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;력&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;서
  </TD>
 </TR>

 "성 명", "(인)", "주민등록번호" 주석 입력, '이름' 템플리트 입력
 <TR>
  <TD width='15%' rowspan='2' class="theader" style="text-align: center">
   성&nbsp;&nbsp;&nbsp;&nbsp;명
  </TD>    
  <TD width='35%' rowspan='2' class="theader" style="text-align: right">
   현재 위치에 다음 템플리트를 매치("이력서"의 하위 노드중 "이름" 에 해당하는 템플리트 매치)
   <xsl:apply-templates select="이름"/>
   (인)
  </TD>
  <TD width='40%' height="25pt" colspan='3' class="theader" style="text-align: center">
   주 민 등 록 번 호
  </TD>
 </TR>
 
 '주민등록번호' 템플리트 입력
 <TR>
  <TD width='40%' height="25pt" colspan='3' class="theader" style="text-align: center">
   현재 위치에 다음 템플리트를 매치("이력서"의 하위 노드중 "주민등록번호" 에 해당하는 템플리트 매치)
   <xsl:apply-templates select="주민등록번호"/>
  </TD>
 </TR>

 '생년월일' 템플리트 입력
 <TR>
  <TD colspan='5' height="50pt" class="theader" style="text-align: center">
   현재 위치에 다음 템플리트를 매치("이력서"의 하위 노드중 "생년월일" 에 해당하는 템플리트 매치)
   <xsl:apply-templates select="생년월일"/>
  </TD>
 </TR>

 "주 소" 주석 입력, '주소' 템플리트 입력
 <TR>
  <TD colspan='3' class="title" style="text-align: center">
   주&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;소
  </TD>
  <TD colspan='5' class="title" style="text-align: center">
   현재 위치에 다음 템플리트를 매치("이력서"의 하위 노드중 "주소" 에 해당하는 템플리트 매치)
   <xsl:apply-templates select="주소"/>
  </TD>
 </TR>

 "호적관계", "호주와의 관계", "호주성명" 주석입력, '호적관계/관계', '호적관계/호주성명' 템플리트 입력
 <TR>
  <TD colspan='3' class="title" width="10%" style="text-align: center">
   호적관계
  </TD>
  <TD class="title" width="17%" style="text-align: center">
   호주와의 관계
  </TD>
  <TD class="title" width="30%" style="text-align: center">
   현재 위치에 다음 템플리트를 매치("이력서"의 하위 노드중 "호적관계/관계" 에 해당하는 템플리트 매치)
   <xsl:apply-templates select="호적관계/관계"/>
  </TD>
  <TD class="title" width="13%" style="text-align: center">
   호 주 성 명
  </TD>
  <TD colspan='2' class="title" style="text-align: center">
   현재 위치에 다음 템플리트를 매치("이력서"의 하위 노드중 "호적관계/호주성명" 에 해당하는 템플리트 매치)
   <xsl:apply-templates select="호적관계/호주성명"/>
  </TD>
 </TR>

 "년월일", "학력사항", "발령청" 주석 입력
 <TR>
  <TD class="comment" colspan='3' style="text-align: center">
   년 월 일
  </TD>
  <TD class="comment" colspan='4' style="font-weight: bold; text-align: center">
   학 력 사 항
  </TD>
  <TD class="comment" width="18%" style="text-align: center">
   발 령 청
  </TD>
 </TR>

 현재 위치에 다음 템플리트를 매치("이력서"의 하위 노드중 "학력" 에 해당하는 템플리트 매치)
 <xsl:apply-templates select="학력"/>
 
 "이력서"의 하위에 "자격" 노드가 하나 이상 존재하면 "자격사항" 주석 입력
 <xsl:if test="count(자격) > 0">
  <TR>
   <TD class="comment" colspan='8' style="font-weight: bold; text-align: center">
    자 격 사 항
   </TD>
  </TR>
 </xsl:if>
 
 현재 위치에 다음 템플리트를 매치("이력서"의 하위 노드중 "자격" 에 해당하는 템플리트 매치)
 <xsl:apply-templates select="자격"/>
 
 "이력서"의 하위에 "특기" 노드가 하나 이상 존재하면 "특기사항" 주석 입력
 <xsl:if test="count(특기) > 0">
  <TR>
   <TD class="comment" colspan='8' style="font-weight: bold; text-align: center">
    특 기 사 항 
   </TD>
  </TR>
 </xsl:if>
 
 현재 위치에 다음 템플리트를 매치("이력서"의 하위 노드중 "특기" 에 해당하는 템플리트 매치)
 <xsl:apply-templates select="특기"/>
 
 "이력서"의 하위에 "경력" 노드가 하나 이상 존재하면 "경력사항" 주석 입력
 <xsl:if test="count(경력) > 0">
  <TR>
   <TD class="comment" colspan='8' style="font-weight: bold; text-align: center">
    경 력 사 항 
   </TD>
  </TR>
 </xsl:if>
 
 현재 위치에 다음 템플리트를 매치("이력서"의 하위 노드중 "경력" 에 해당하는 템플리트 매치)
 <xsl:apply-templates select="경력"/>
 
 </TABLE>
</xsl:template>

특별한 처리를 요하는 부분은 유지보수를 위해 별도의 템플리트로 구성한다.

[ ! ] XSLT의 함수로 있는 unparsed-entity-uri는 엔티티이름에 따른 엔티티 값을 리턴하는 함수다. 보통, 외부 엔티티를 선언한후 이를 참조할때 사용한다. 속성에서 많이 사용하는데 속성타입을 ENTITY 로 하고, 속성값에 엔티티 이름을 사용한다.

현재의 컨택스트 노드가 "사진" 으로써 템플리트에 매치된다.
<xsl:template match = "사진">
 <img>
  IMG 엘리먼트의 속성으로 "ID" 를 생성한다.
  <xsl:attribute name="ID">
   IMG 엘리먼트 ID의 속성값으로 현재 컨택스트 노드인 "사진"의 속성 "ID" 값을 넣는다.
   <xsl:value-of select="@ID"/>
  </xsl:attribute>
  IMG 엘리먼트의 속성으로 "src" 를 생성한다.
  <xsl:attribute name="src">
   IMG 엘리먼트 src의 속성값으로 현재 컨택스트 노드인 "사진"의 속성 "NAME" 값을 넣는다.(위 팁[!] 참조)
   <xsl:value-of select="unparsed-entity-uri(@NAME)"/>   
  </xsl:attribute>
 </img>  
</xsl:template>

다음 소스는 결과 HTML 의 속성값을 연결시키는 템플리트다.

[ ! ] xsl:text를 사용한 텍스트문자열은 일반적으로 텍스트를 입력하는것 보다 문자열 연결시에 화이트스페이스(white-space) 처리에 용이하다.

현재의 컨택스트 노드가 "이름" 으로써 템플리트에 매치된다.
<xsl:template match = "이름">
 <a>
  A 엘리먼트의 속성으로 "HREF" 를 생성한다.
  <xsl:attribute name="HREF">
   "mailto:" 값을 A 엘리먼트 HREF의 속성값으로 입력
   <xsl:text>mailto:</xsl:text>
   문서에서 첫번째로 접근되는 "전자우편번호"를 A 엘리먼트 HREF의 속성값으로 이어서 입력
   <xsl:value-of select="//전자우편번호[1]"/>
  </xsl:attribute>
  A 엘리먼트의 내부 값으로, 현재 컨택스트 노드인 "이름" 노드의 텍스트 데이터값을 입력
  <xsl:value-of select="."/>
 </a>
</xsl:template>

다음 소스는 xsl:text와 xsl:value-of를 사용해 여러 문자열을 하나의 문자열로 만드는 템플리트다.

현재의 컨택스트 노드가 "생년월일" 으로써 템플리트에 매치된다.
<xsl:template match = "생년월일">
 <xsl:text>생년월일</xsl:text>
 <xsl:text>서기</xsl:text>
 <xsl:value-of select = "년"/>
 <xsl:text>년</xsl:text>
 <xsl:value-of select = "월"/>
 <xsl:text>월</xsl:text>
 <xsl:value-of select = "일"/>
 <xsl:text>일생</xsl:text>
 <xsl:text>(만 </xsl:text>
 <xsl:value-of select = "나이"/>
 <xsl:text> 세)</xsl:text>
</xsl:template>

다음 소스는 xsl:value-of를 사용해 여러 문자열을 하나의 문자열로 만드는 템플리트다.

현재의 컨택스트 노드가 "생년월일" 으로써 템플리트에 매치된다.
<xsl:template match = "주민등록번호">
 <xsl:value-of select = "앞자리"/> - 
 <xsl:value-of select = "뒷자리"/>     
</xsl:template>

다음 소스는 필요한 노드만 입력하는 템플리트다.

[ ! ] Mixed Content 즉, 엘리먼트와 #PCDATA가 함께 형제노드로 존재하는 경우, xsl:for-each와 xsl:choose 를 사용해 원하는 노드만 처리할 수 있다.

현재의 컨택스트 노드가 "주소" 으로써 템플리트에 매치된다.
<xsl:template match = "주소">
 node()는 현재 컨택스트 노드 즉, "주소"의 하위 노드들을 의미한다.(위 팁[!] 참조)
 <xsl:for-each select="node()">
  <xsl:choose>
   엘리먼트 노드일 경우는 아무것도 않한다.
   <xsl:when test="local-name(.)='전화번호'"/>
   <xsl:when test="local-name(.)='전자우편번호'"/>
   일반 텍스트(#PCDATA) 경우에는 현재 컨택스트 즉, text() 노드를 입력한다.
   <xsl:otherwise>
    <xsl:value-of select="."/>
   </xsl:otherwise>
  </xsl:choose>
 </xsl:for-each>
</xsl:template>

다음 소스는 반복되는 패턴의 처리를 위한 템플리트다.

[ ! ] xsl:value-of 의 선택 노드값이나 xsl:apply-templates 의 선택될 템플리트가 없다면, 아무값도 입력되지 않는다. 그러므로 단말(Termial) 노드 처리시에는 xsl:if 나 xsl:choose 를 사용할 필요가 없다.

현재의 컨택스트 노드가 "학력" 혹은 "경력" 혹은 "자격" 혹은 "특기" 로써 템플리트에 매치된다.
<xsl:template match = "학력|경력|자격|특기">
 <TR>
  <TD class='titem' width="7%" style="text-align: center">
   컨택스트 노드의 하위 노드가 "년" 노드가 아니면 "-"을 입력
   <xsl:if test="true()!=current()[년]">
    <div class="null">-</div>
   </xsl:if>
   컨택스트 노드의 하위 노드중 "년" 노드가 있으면 값을 입력
   <xsl:value-of select = "년"/>
  </TD>
  <TD class='titem' width="4%" style="text-align: center">
   <xsl:if test="true()!=current()[월]">
    <div class="null">-</div>
   </xsl:if>
   <xsl:value-of select = "월"/>
  </TD>
  <TD class='titem' width="4%" style="text-align: center">
   <xsl:if test="true()!=current()[일]">
    <div class="null">-</div>
   </xsl:if>
   <xsl:value-of select = "일"/>
  </TD>
  <TD class='titem' colspan='4' style="text-align: center">
   <xsl:if test="true()!=current()[내용]">
    <div class="null">-</div>
   </xsl:if>
   <xsl:value-of select = "내용"/>
  </TD>
  <TD class='titem' width="15%" style="text-align: center">
   <xsl:if test="true()!=current()[비고]">
    <div class="null">-</div>
   </xsl:if>
   <xsl:value-of select = "비고"/>
  </TD>
 </TR>
</xsl:template>

</xsl:stylesheet>

7. XSL Stylesheet 예제 (3)

이번엔 본 강좌의 스타일 시트를 살펴본다.

7.1 강좌 DTD

다음 강좌 DTD는 Internet Explorer 에 적합하도록 설계되었으며, 최적화된 DTD는 아니다.

다음은 강좌.dtd 이다.

<?xml version="1.0" encoding="euc-kr"?>
<!-- copyright ⓒ HyoungMoon, Lee -->
<!-- darkness@nate.com -->
<!-- http://home.kcnet5.com/darkness/ -->
<!-- draft  date : 2000/12/20  -->
<!-- update date : 2001/01/05  -->

<!NOTATION jpg PUBLIC "">

<!ENTITY % e.ph "단락|그림그룹|문자데이터|팁|표">
<!ENTITY % m.ph "#PCDATA|강조|연결">

<!ENTITY % a.ep "색 CDATA #IMPLIED
   배경색 CDATA #IMPLIED
   두께 CDATA #IMPLIED
   스타일 CDATA #IMPLIED">

<!ENTITY % a.link "위치 CDATA #IMPLIED">


<!-- Top-level ELEMENT  -->
<!-- =================  -->
<!ELEMENT 강좌 (제목,목차?,내용,저작권?)>

<!ELEMENT 내용 (장)+>
<!ELEMENT 장 (제목,(%e.ph;)*,절*)>
<!ATTLIST 장 목차 CDATA #IMPLIED>

<!ELEMENT 절 (제목,(%e.ph;)*)>


<!-- List ELEMENT  -->
<!-- ============  -->
<!ELEMENT 목차 (목록)+>
<!ELEMENT 목록 (#PCDATA)>


<!-- Table ELEMENT  -->
<!-- =============  -->
<!ELEMENT 표 (표머리?,표꼬리?,(표내용*|행+))>
<!ELEMENT 표머리 (행)+>
<!ELEMENT 표꼬리 (행)+>
<!ELEMENT 표내용 (행)+>
<!ELEMENT 행 (열)+>
<!ELEMENT 열 (%e.ph;)*>


<!-- Image ELEMENT  -->
<!-- =============  -->
<!ELEMENT 그림그룹 (그림|제목)*>
<!ELEMENT 그림 EMPTY>
<!ATTLIST 그림 이름 ENTITY #IMPLIED>


<!-- block ELEMENT  -->
<!-- =============  -->
<!ELEMENT 저작권 (단락)+>

<!ELEMENT 단락 (%m.ph;)*>
<!ATTLIST 단락 %a.ep;>

<!ELEMENT 문자데이터 (%m.ph;)*>
<!ATTLIST 문자데이터 %a.ep;>

<!ELEMENT 팁 (%m.ph;)*>
<!ATTLIST 팁 %a.ep;>

<!ELEMENT 제목 (#PCDATA)>
<!ATTLIST 제목 %a.ep;>


<!-- inline ELEMENT  -->
<!-- ==============  -->
<!ELEMENT 강조 (#PCDATA)>
<!ATTLIST 강조 %a.ep;>

<!ELEMENT 연결 (#PCDATA)>
<!ATTLIST 연결 %a.ep; %a.link;>

위의 DTD는 단순하면서도 복잡하기 때문에 문서의 구조를 나타내기 위한 DTD Diagram을 그림1 과 그림2 에 보인다.

[ ! ] 주의 : DTD Diagram 에는 어트리뷰트 에 관계되는 부분이 생략되어 있다.

[그림 1] 강좌 DTD Diagram (1)

[그림 2] 강좌 DTD Diagram (2)

7.2 강좌 XML 문서

다음은 강좌예제.xml 이다.

<?xml version="1.0" encoding="euc-kr"?>
<!-- copyright ⓒ HyoungMoon, Lee  -->
<!-- darkness@nate.com  -->
<!-- http://home.kcnet5.com/darkness/  -->
<!-- draft  date : 2000/12/21  -->
<!-- update date : 2001/01/05  -->
<?xml-stylesheet type="text/xsl" class='MIME' href="강좌.xsl"?>
<!DOCTYPE 강좌 SYSTEM "강좌.dtd"[
<!ENTITY 목차 PUBLIC "-//Darkness//TEXT data//EN" "목차.xml">
<!ENTITY 저작권 PUBLIC "-//Darkness//TEXT data//EN" "저작권.xml">
<!ENTITY 그림01 SYSTEM "03.jpg"   NDATA     jpg>
<!ENTITY 그림02 SYSTEM "04.jpg"   NDATA     jpg>
]>
<강좌>

<제목>XSL 기초</제목>
&목차;
<내용>
 <장 목차="02">
  <제목>2. XSLT 이해(1)</제목>
  <단락>XSLT 표준안 상태에 대해..</단락>
  <단락>XSLT는 1999년 ... <연결 위치="http://www.w3.org/TR/xslt">XSLT 1.0</연결> ... </단락>

  <절>
   <제목>2.1 XSLT 처리 개념</제목>
   <단락>템플리트룰은 XSLT 지시...</단락>

   <그림그룹>
    <그림 이름="그림01"/>
    <제목>[ 그림 1 ] XSLT 처리 개념</제목>
   </그림그룹>

   <단락>그림1의 XSLT 처리 개념도 ... </단락>
  </절>
  <절>
   <제목>2.2 템플리트 매칭(Template Matching)</제목>
   <단락>템플리트 매칭이란 ... </단락>
   
   <문자데이터>
 <<강조 색="green">memo</강조>>
  <to><강조 색="black">홍길동</강조></to>
  <from><강조 색="black">김돌쇠</강조></from>
  <say><강조 색="black">안녕하세요.</강조><say>
 </<강조 색="green">memo</강조>>

 <<강조 색="red">xsl:template</강조><강조 색="purple"> match</강조>=<강조 색="green">"memo"</강조>>
  ...
 </<강조 색="red">xsl:template</강조>>
   </문자데이터>

   <단락>위의 XML 문서는 <강조 색="blue"><memo></강조>엘리먼트를 ... </단락>
   
   <팁>모든 XML 문서의 루트 ... </팁>

   ...

  </절>
  <절>
   <제목>2.3 템플리트 예제</제목>
   <단락>다음은 2.2 의 XML 문서에 대한 완전한 XSL 스타일 시트를 보여준다.</단락>
   <문자데이터>

   ...

   </문자데이터>
   
   <단락>다음 그림2는 위의 템플리트룰들이 처리되는 과정을 보인다.</단락>
   <그림그룹>
    <그림 이름="그림02"/>
    <제목>[ 그림 2 ] 템플리트 매칭 과정</제목>
   </그림그룹>

   ...

  </절>
 </장>
</내용>
&저작권;
</강좌>

[ ! ] 목차와 저작권는 유지보수및 독립적인 사용을 위해 각각 독립된 문서로 구성한다.

다음은 목차.xml 이다.

<?xml version="1.0" encoding="euc-kr"?>
<!-- copyright ⓒ HyoungMoon, Lee  -->
<!-- darkness@nate.com  -->
<!-- http://home.kcnet5.com/darkness/  -->
<!-- draft  date : 2000/12/20  -->
<!-- update date : 2000/12/20  -->
<목차>
 <목록>XSL 구조</목록>
 <목록>XSLT 이해(1)</목록>
 <목록>XSLT 이해(2)</목록>
 <목록>XPath 이해</목록>
 <목록>XSL Stylesheet 예제 (1)</목록>
 <목록>XSL Stylesheet 예제 (2)</목록>
 <목록>XSL Stylesheet 예제 (3)</목록>
 <목록>XSL Stylesheet 예제 (4)</목록>
</목차>

다음은 저작권.xml 이다.

<?xml version="1.0" encoding="euc-kr"?>
<!-- copyright ⓒ HyoungMoon, Lee  -->
<!-- darkness@nate.com  -->
<!-- http://home.kcnet5.com/darkness/  -->
<!-- draft  date : 2001/01/05  -->
<!-- update date : 2001/01/05  -->
<저작권>
 <단락>본 강좌내용과 데이터의 저작권 및 소유권은 
 <연결 위치="mailto:darkness@nate.com?subject=강좌문의">이형문</연결> 에게 있습니다.
 개인 사용자가 자료의 배포시 무단 수정을 금지하며, 반드시 출처를 명시해야 합니다.
 회사의 경우 자료의 무단 등록, 배포및 수정을 금지하며, 반드시 본인의 허락을 받아야 합니다.
 또한, 본 자료의 사용으로 생기는 피해등의 관한 책임은 저에게 없습니다.</단락>
</저작권>

7.3 강좌 XSL 스타일시트

다음은 강좌.xsl 이다.

다음의 강좌 XSL 스타일시트를 구성하기 위해 다음과 같은 단계를 거친다.

1. 그림1 과 그림2의 DTD Diagram을 분석한다.

먼저 그림1과 그림2의 DTD Diagram을 분석해보면, "강좌"는 크게 "목차", "내용", "저작권" 으로 나뉜다. 다음으로 세부적인 사항은 실제 포맷팅에 관련하여 나눌수 있다. 예를 들어 블럭 단위인 "단락,그림그룹,문자데이터,팁,표" 와 인라인 단위 "강조, 연결, #PCDATA" 로 나눌수 있다.

2. 분석에따라 유지보수를 위한 템플리트를 계획한다.

"목차"와 "저작권"은 유지 보수를 위해 각각 독립적인 템플리트를 작성하고 나중에 연결시킨다. "내용"은 "목차", "저작권" 과 더블어 삽입될 순서를 고려하며,하위 템플리트를 매칭시킨다. "단락"과 "팁"은 포맷팅 계획에 따라 같이 처리하도록 템플리트를 구성하며, "그림그룹", "문자데이터", "표" 또한 각각의 템플리트를 작성한다. 적용할 포맷팅 모듈이 HTML 이므로 속성값으로 처리해야 할 정보는 각각 템플리트로 구성하고, 필요에 따라 적용 가능하도록 한다.

3. 스타일 시트의 스타일 속성 및 구성을 설계한다.

내용중 "제목"은 여러번 반복되고 각각의 의미에 따라 다른 형태의 템플리트를 작성한다. 속성을 위한 템플리트는 HTML의 Style 속성을 사용하며 각각 독립되도록 유지한다. 결과 포맷팅 모듈로의 변환시의 상태를 위해 포맷팅 모듈의 끝에 &#13;&#10;를 사용하여 단락 처리 한다. 블럭 단위의 스타일 처리는 유지 보수를 위해 각각 HTML의 Class 속성을 사용하여 정의하고 최상위에서 스타일을 정의하도록 한다. 인라인 단위의 처리는 "단락" 및 "팁", "문자데이터" 내부에서 처리되도록 한다.

[ ! ] 스타일 시트의 구성과 유지보수를 위한 템플리트 설계는 DTD의 구조 즉, DTD Diagram을 분석을 통하여 이루어진다.

다음회에 계속......

8. XSL Stylesheet 예제 (4)

8.1 이력서 XSL 스타일시트

다음은 강좌.xsl 이다.

<?xml  : XML declaration
<xsl:..  : XSLT Element & Attribute ...
HTML  : HTML Element
CLASS  : HTML Attribute
목차  : HTML Attribute value
목차  : HTML Text Data value
&#13;&#10; : HTML Text Data value ( for HTML ELEMENT separation )
   
<?xml version="1.0" encoding="euc-kr"?>
 <!-- copyright ⓒ HyoungMoon, Lee -->
 <!-- darkness@nate.com -->
 <!-- http://home.kcnet5.com/darkness/ -->
 <!-- draft  date : 2000/12/20  -->
 <!-- update date : 2001/01/05  --> 
 <xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 
 <xsl:output method="xml" version="1.0" encoding="euc-kr"/>
  
 <xsl:template match="/">
  <xsl:element name="HTML">
   <xsl:element name="STYLE">
    <xsl:text>
     .목차{font-size:9pt; marin-top:10pt; margin-bottom:10pt}
     .목차선택{background-color:ccffff}
     .저작권{color:red; background-color:Beige}
     .저작권강조{color:blue;background-color:LightCyan;text-align:center;}
     .그림그룹{text-align: center;margin-bottom:20pt;font-weight:bold}
     .강좌제목{color:blue; font-size:20pt; font-family:Arial; font-weight:bold; margin-top:10pt; margin-bottom:10pt}
     .장{margin-top:10pt; margin-bottom:10pt}
     .절{margin-top:10pt; margin-bottom:10pt}
     .단락{margin-bottom:10pt}
     .팁{margin-bottom:10pt; background-color:yellow}
     .팁강조{color:red; font-weight:bold}
     .문자데이터{color:blue;font-size:9pt}
     .표{margin-top:10pt; margin-bottom:10pt; margin-left:100pt; margin-right:100pt; table-layout:fixed}
     .표머리{text-weight:bold; color:red}
     .표내용{vertical-align:top}
     .장제목{font-size:15pt;font-weight:bold;margin-bottom:10pt}
     .절제목{font-size:13pt;font-weight:bold;margin-bottom:10pt}
     BODY{margin-left: 30pt;margin-right: 30pt;text-align:justify; font-size:11pt;}
    </xsl:text>
   </xsl:element>   
   <xsl:element name="BODY">
    <xsl:apply-templates select="강좌"/>
   </xsl:element>
  </xsl:element>
 </xsl:template>


 <!--================= 목차 =================-->


 <xsl:template name="목차메뉴">
  <xsl:element name="DIV">
   <xsl:attribute name="CLASS">
    <xsl:text>목차</xsl:text>
   </xsl:attribute>
   <xsl:for-each select="//목차/목록">
    <xsl:element name="DIV">
     <xsl:element name="SPAN">
      <xsl:if test="position()=number(//장/@목차)">
       <xsl:attribute name="CLASS">
        <xsl:text>목차선택</xsl:text>
       </xsl:attribute>
      </xsl:if>
      <xsl:value-of select="position()"/>
      <xsl:text>. </xsl:text>
      <xsl:value-of select="."/>
     </xsl:element>
    </xsl:element>
    <xsl:text>&#13;&#10;</xsl:text>
   </xsl:for-each>
  </xsl:element>
  <xsl:text>&#13;&#10;</xsl:text>
 </xsl:template>


 <!--================= 저작권 =================-->


 <xsl:template name="저작권">
  <xsl:element name="DIV">
   <xsl:attribute name="CLASS">
    <xsl:text>저작권</xsl:text>
   </xsl:attribute>
   <xsl:element name="DIV">
    <xsl:attribute name="CLASS">
     <xsl:text>저작권강조</xsl:text>
    </xsl:attribute>
    <xsl:text>Copyright ⓒ HyoungMoon, Lee</xsl:text>
   </xsl:element>
   <xsl:apply-templates select="//저작권/단락"/>
  </xsl:element>
  <xsl:text>&#13;&#10;</xsl:text>
 </xsl:template>


 <!--================= 템플리트 =================-->


 <xsl:template match="강좌">
  <xsl:text>&#13;&#10;</xsl:text>
  <xsl:element name="DIV">
   <xsl:attribute name="CLASS">
    <xsl:text>강좌제목</xsl:text>
   </xsl:attribute>
   <xsl:value-of select="/강좌/제목"/>
  </xsl:element>
  <xsl:text>&#13;&#10;</xsl:text>
  <xsl:call-template name="목차메뉴"/>
  <xsl:apply-templates select="내용"/>
  <xsl:call-template name="저작권"/>
 </xsl:template>

 <xsl:template match="내용">
  <xsl:apply-templates/>
 </xsl:template>

 <xsl:template match="장">
  <xsl:element name="DIV">
   <xsl:attribute name="CLASS">
    <xsl:text>장</xsl:text>
   </xsl:attribute>
   <xsl:apply-templates/>
  </xsl:element>
  <xsl:text>&#13;&#10;</xsl:text>
 </xsl:template>

 <xsl:template match="절">
  <xsl:element name="DIV">
   <xsl:attribute name="CLASS">
    <xsl:text>절</xsl:text>
   </xsl:attribute>
   <xsl:apply-templates/>
  </xsl:element>
  <xsl:text>&#13;&#10;</xsl:text>
 </xsl:template>


 <!--================= 단락,팁,문자데이터  =================-->


 <xsl:template match="단락|팁">
  <xsl:element name="DIV">
   <xsl:if test="local-name()='팁'">
    <xsl:attribute name="CLASS">
     <xsl:text>팁</xsl:text>
    </xsl:attribute>
    <xsl:element name="SPAN">
     <xsl:attribute name="CLASS">
      <xsl:text>팁강조</xsl:text>
     </xsl:attribute>
     <xsl:text>[ ! ] </xsl:text>
    </xsl:element>
   </xsl:if>
   <xsl:if test="local-name()='단락'">
    <xsl:attribute name="CLASS">
     <xsl:text>단락</xsl:text>
    </xsl:attribute>
   </xsl:if>
   <xsl:apply-templates select="@*"/>
   <xsl:for-each select="node()">
    <xsl:choose>
     <xsl:when test="local-name()='강조'">
      <xsl:element name="SPAN">
       <xsl:apply-templates select="@*"/>
       <xsl:apply-templates select="."/>
      </xsl:element>
     </xsl:when>
     <xsl:when test="local-name()='연결'">
      <xsl:element name="A">
       <xsl:apply-templates select="@*"/>
       <xsl:apply-templates select="."/>
      </xsl:element>
     </xsl:when>
     <xsl:otherwise>
      <xsl:apply-templates select="."/>
     </xsl:otherwise>
    </xsl:choose>
   </xsl:for-each>
  </xsl:element>
  <xsl:text>&#13;&#10;</xsl:text>
 </xsl:template>

 <xsl:template match="문자데이터">
  <xsl:element name="PRE">
   <xsl:attribute name="CLASS">
    <xsl:text>문자데이터</xsl:text>
   </xsl:attribute>
   <xsl:apply-templates select="@*"/>
   <xsl:for-each select="./node()">
    <xsl:choose>
     <xsl:when test="local-name()='강조'">
      <xsl:element name="SPAN">
       <xsl:apply-templates select="@*"/>
       <xsl:apply-templates select="."/>
      </xsl:element>
     </xsl:when>
     <xsl:when test="local-name()='연결'">
      <xsl:element name="A">
       <xsl:apply-templates select="@*"/>
       <xsl:apply-templates select="."/>
      </xsl:element>
     </xsl:when>
     <xsl:otherwise>
      <xsl:apply-templates select="."/>
     </xsl:otherwise>
    </xsl:choose>
   </xsl:for-each>
  </xsl:element>
  <xsl:text>&#13;&#10;</xsl:text>
 </xsl:template>

 
 <!--================= 그림 =================-->
 

 <xsl:template match="그림그룹">
  <xsl:element name="DIV">
   <xsl:attribute name="CLASS">
    <xsl:text>그림그룹</xsl:text>
   </xsl:attribute>
   <xsl:element name="IMG">
    <xsl:attribute name="SRC">
     <xsl:value-of select="unparsed-entity-uri(그림/@이름)"/>
    </xsl:attribute>
   <xsl:text>&#13;&#10;</xsl:text>
   </xsl:element>
   <xsl:element name="DIV">
    <xsl:value-of select="제목"/>
   <xsl:text>&#13;&#10;</xsl:text>
   </xsl:element>
  </xsl:element>
  <xsl:text>&#13;&#10;</xsl:text>
 </xsl:template>


 <!--================= 표 =================-->


 <xsl:template match="표">
  <xsl:element name="TABLE">
   <xsl:attribute name="CLASS">
    <xsl:text>표</xsl:text>
   </xsl:attribute>
   <xsl:element name="THEAD">   
    <xsl:attribute name="CLASS">
     <xsl:text>표머리</xsl:text>
    </xsl:attribute>
    <xsl:apply-templates select="표머리"/>
   <xsl:text>&#13;&#10;</xsl:text>
   </xsl:element>
   <xsl:element name="TFOOT">   
    <xsl:attribute name="CLASS">
     <xsl:text>표꼬리</xsl:text>
    </xsl:attribute>
    <xsl:apply-templates select="표꼬리"/>
   <xsl:text>&#13;&#10;</xsl:text>
   </xsl:element>
   <xsl:element name="TBODY">   
    <xsl:attribute name="CLASS">
     <xsl:text>표내용</xsl:text>
    </xsl:attribute>
    <xsl:apply-templates select="표내용|행"/>
   <xsl:text>&#13;&#10;</xsl:text>
   </xsl:element>
  <xsl:text>&#13;&#10;</xsl:text>
  </xsl:element>
 </xsl:template>

 <xsl:template match="행">
  <xsl:element name="TR">
   <xsl:apply-templates/>
  </xsl:element>
  <xsl:text>&#13;&#10;</xsl:text>
 </xsl:template>

 <xsl:template match="열">
  <xsl:element name="TD">
   <xsl:apply-templates/>
  </xsl:element>
  <xsl:text>&#13;&#10;</xsl:text>
 </xsl:template>


 <!--================= 제목 =================-->


 <xsl:template match="장/제목">
  <xsl:element name="DIV">
   <xsl:attribute name="CLASS">
    <xsl:text>장제목</xsl:text>
   </xsl:attribute>
   <xsl:element name="SPAN">
    <xsl:apply-templates select="@*"/>
    <xsl:value-of select="."/>
   </xsl:element>
  </xsl:element>  
  <xsl:text>&#13;&#10;</xsl:text>
 </xsl:template>

 <xsl:template match="절/제목">
  <xsl:element name="DIV">
   <xsl:attribute name="CLASS">
    <xsl:text>절제목</xsl:text>
   </xsl:attribute>
   <xsl:element name="SPAN">
    <xsl:apply-templates select="@*"/>
    <xsl:value-of select="."/>
   </xsl:element>
  </xsl:element>  
  <xsl:text>&#13;&#10;</xsl:text>
 </xsl:template>


 <!--================= 속성 =================-->


 <xsl:template match="@색">
  <xsl:attribute name="STYLE">
   <xsl:text>color:</xsl:text>
   <xsl:value-of select="."/>
  </xsl:attribute>
 </xsl:template>

 <xsl:template match="@두께">
  <xsl:attribute name="STYLe">
   <xsl:text>font-weight:</xsl:text>
   <xsl:value-of select="."/>
  </xsl:attribute>
 </xsl:template>

 <xsl:template match="@스타일">
  <xsl:attribute name="style">
   <xsl:text>font-style:</xsl:text>
   <xsl:value-of select="."/>
  </xsl:attribute>
 </xsl:template>
 
 <xsl:template match="@배경색">
  <xsl:attribute name="stylE">
   <xsl:text>background-color:</xsl:text>
   <xsl:value-of select="."/>
  </xsl:attribute>
 </xsl:template>
 

 <xsl:template match="@위치">
  <xsl:attribute name="HREF">
   <xsl:value-of select="."/>
  </xsl:attribute>
  <xsl:attribute name="TARGET">
   <xsl:text>new</xsl:text>
  </xsl:attribute>
 </xsl:template>
</xsl:stylesheet>

Copyright ⓒ HyoungMoon, Lee

본 강좌내용과 데이터의 저작권 및 소유권은 이형문 에게 있습니다. 개인 사용자가 자료의 배포시 무단 수정을 금지하며, 반드시 출처를 명시해야 합니다. 회사의 경우 자료의 무단 등록, 배포및 수정을 금지하며, 반드시 본인의 허락을 받아야 합니다. 또한, 본 자료의 사용으로 생기는 피해등의 관한 책임은 저에게 없습니다.

 

- 저자 주 -

xml 데이터를 변환한 형태라 데이터가 깨질 수 도 있습니다.

데이터의 오류가 있을 경우 질타 부탁합니다. ^^;

하드 저 먼 지하 구석에 쳐 박혀 있던 글을 요 아래 강자 올린 후배덕에 빛을 보게 됐네요.

추후 자세한 강좌 또 올리겠습니다.